mirror of
https://github.com/bitcoin/bitcoin.git
synced 2025-03-22 15:52:03 +01:00
da3ed8b970
2c4b229c906de6250500d3af2b44808e90b9ce0b cmake: Introduce `FUZZ_LIBS` (Hennadii Stepanov)
ea929c0848e2d95a71439e1b3aa0cf350e12bc73 scripted-diff: Rename CMake helper module (Hennadii Stepanov)
8d238c1dfde28bbd38bfba84136900724c0d7d95 cmake: Delete `check_cxx_source_links*` macros (Hennadii Stepanov)
71bf8294a985d818a9d855390bd8503a9ae8074a cmake: Convert `check_cxx_source_compiles_with_flags` to a function (Hennadii Stepanov)
88ee6800c9686931a1550b41fa634b0c6c3988a7 cmake: Delete `check_cxx_source_links_with_flags` macro (Hennadii Stepanov)
09e8fd25b1a5411472564e599ad15059bbf9e8d6 build: Don't override CMake's default try_compile target (Hennadii Stepanov)
Pull request description:
This was requested in https://github.com/bitcoin/bitcoin/pull/31359#issuecomment-2515287092.
From https://github.com/bitcoin/bitcoin/pull/31359#issuecomment-2511246212:
> (Almost?) every CMake check internally uses the [`try_compile()`](https://cmake.org/cmake/help/latest/command/try_compile.html) command, whose behaviour, in turn, depends on the [`CMAKE_TRY_COMPILE_TARGET_TYPE`](https://cmake.org/cmake/help/latest/variable/CMAKE_TRY_COMPILE_TARGET_TYPE.html) variable:
>
> 1. The default value, `EXECUTABLE`, enables both compiler and linker checks.
>
> 2. The `STATIC_LIBRARY` value enables only compiler checks.
>
>
> To mimic Autotools' behaviour, we [disabled](d3f42fa08f/cmake/module/CheckSourceCompilesAndLinks.cmake (L9-L10)) linker checks by setting `CMAKE_TRY_COMPILE_TARGET_TYPE` to `STATIC_LIBRARY` globally (perhaps not the best design). This effectively separates the entire CMake script into regions where `CMAKE_TRY_COMPILE_TARGET_TYPE` is:
>
> * unset
>
> * set to `STATIC_LIBRARY`
>
> * set to `EXECUTABLE`
From https://github.com/bitcoin/bitcoin/pull/31359#issuecomment-2515287092:
> > This seems very fragile and unintuitive, and the fact that this could silently break at any point is not documented in any way. I don't think other bad design decisions should lead to us having to write even more boilerplate code to fix things that should "just work" (minus the upstream bugs).
>
> Agreed. I forgot that we set `CMAKE_TRY_COMPILE_TARGET_TYPE` globally. And even worse, it's buried in a module. If that upsets CMake internal tests, I think we should undo that.
This PR ensures that `CMAKE_TRY_COMPILE_TARGET_TYPE` is modified only within local scopes.
Additionally, the `FUZZ_LIBS` variable has been introduced to handle additional libraries required for linking, rather than link options, in certain build environment, such as OSS-Fuzz.
ACKs for top commit:
TheCharlatan:
Re-ACK 2c4b229c906de6250500d3af2b44808e90b9ce0b
theuni:
utACK 2c4b229c906de6250500d3af2b44808e90b9ce0b
Tree-SHA512: f72ffa8f50f216fc1a2f8027ba8ddfd4acd42b94ff6c1cb2138f2da51eb8f945660e97d3c247d7f3f7ec8dfebbccec3ab84347d6ae2e3f8a40f3d7aa8b14cde9
116 lines
3.1 KiB
CMake
116 lines
3.1 KiB
CMake
# Copyright (c) 2023-present The Bitcoin Core developers
|
|
# Distributed under the MIT software license, see the accompanying
|
|
# file COPYING or https://opensource.org/license/mit/.
|
|
|
|
# This file is part of the transition from Autotools to CMake. Once CMake
|
|
# support has been merged we should switch to using the upstream CMake
|
|
# buildsystem.
|
|
|
|
include(CheckCXXSourceCompiles)
|
|
include(CheckSourceCompilesWithFlags)
|
|
|
|
# Check for __builtin_prefetch support in the compiler.
|
|
check_cxx_source_compiles("
|
|
int main() {
|
|
char data = 0;
|
|
const char* address = &data;
|
|
__builtin_prefetch(address, 0, 0);
|
|
return 0;
|
|
}
|
|
" HAVE_BUILTIN_PREFETCH
|
|
)
|
|
|
|
# Check for _mm_prefetch support in the compiler.
|
|
check_cxx_source_compiles("
|
|
#if defined(_MSC_VER)
|
|
#include <intrin.h>
|
|
#else
|
|
#include <xmmintrin.h>
|
|
#endif
|
|
|
|
int main() {
|
|
char data = 0;
|
|
const char* address = &data;
|
|
_mm_prefetch(address, _MM_HINT_NTA);
|
|
return 0;
|
|
}
|
|
" HAVE_MM_PREFETCH
|
|
)
|
|
|
|
# Check for SSE4.2 support in the compiler.
|
|
if(MSVC)
|
|
set(SSE42_CXXFLAGS /arch:AVX)
|
|
else()
|
|
set(SSE42_CXXFLAGS -msse4.2)
|
|
endif()
|
|
check_cxx_source_compiles_with_flags("
|
|
#include <cstdint>
|
|
#if defined(_MSC_VER)
|
|
#include <intrin.h>
|
|
#elif defined(__GNUC__) && defined(__SSE4_2__)
|
|
#include <nmmintrin.h>
|
|
#endif
|
|
|
|
int main() {
|
|
uint64_t l = 0;
|
|
l = _mm_crc32_u8(l, 0);
|
|
l = _mm_crc32_u32(l, 0);
|
|
l = _mm_crc32_u64(l, 0);
|
|
return l;
|
|
}
|
|
" HAVE_SSE42
|
|
CXXFLAGS ${SSE42_CXXFLAGS}
|
|
)
|
|
|
|
# Check for ARMv8 w/ CRC and CRYPTO extensions support in the compiler.
|
|
set(ARM64_CRC_CXXFLAGS -march=armv8-a+crc+crypto)
|
|
check_cxx_source_compiles_with_flags("
|
|
#include <arm_acle.h>
|
|
#include <arm_neon.h>
|
|
|
|
int main() {
|
|
#ifdef __aarch64__
|
|
__crc32cb(0, 0); __crc32ch(0, 0); __crc32cw(0, 0); __crc32cd(0, 0);
|
|
vmull_p64(0, 0);
|
|
#else
|
|
#error crc32c library does not support hardware acceleration on 32-bit ARM
|
|
#endif
|
|
return 0;
|
|
}
|
|
" HAVE_ARM64_CRC32C
|
|
CXXFLAGS ${ARM64_CRC_CXXFLAGS}
|
|
)
|
|
|
|
add_library(crc32c STATIC EXCLUDE_FROM_ALL
|
|
${PROJECT_SOURCE_DIR}/src/crc32c/src/crc32c.cc
|
|
${PROJECT_SOURCE_DIR}/src/crc32c/src/crc32c_portable.cc
|
|
)
|
|
target_compile_definitions(crc32c PRIVATE
|
|
HAVE_BUILTIN_PREFETCH=$<BOOL:${HAVE_BUILTIN_PREFETCH}>
|
|
HAVE_MM_PREFETCH=$<BOOL:${HAVE_MM_PREFETCH}>
|
|
HAVE_STRONG_GETAUXVAL=$<BOOL:${HAVE_STRONG_GETAUXVAL}>
|
|
BYTE_ORDER_BIG_ENDIAN=$<STREQUAL:${CMAKE_CXX_BYTE_ORDER},BIG_ENDIAN>
|
|
HAVE_SSE42=$<BOOL:${HAVE_SSE42}>
|
|
HAVE_ARM64_CRC32C=$<BOOL:${HAVE_ARM64_CRC32C}>
|
|
)
|
|
target_include_directories(crc32c
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/src/crc32c/include>
|
|
)
|
|
target_link_libraries(crc32c PRIVATE core_interface)
|
|
set_target_properties(crc32c PROPERTIES EXPORT_COMPILE_COMMANDS OFF)
|
|
|
|
if(HAVE_SSE42)
|
|
set(_crc32_src ${PROJECT_SOURCE_DIR}/src/crc32c/src/crc32c_sse42.cc)
|
|
target_sources(crc32c PRIVATE ${_crc32_src})
|
|
set_property(SOURCE ${_crc32_src} PROPERTY COMPILE_OPTIONS ${SSE42_CXXFLAGS})
|
|
endif()
|
|
|
|
if(HAVE_ARM64_CRC32C)
|
|
set(_crc32_src ${PROJECT_SOURCE_DIR}/src/crc32c/src/crc32c_arm64.cc)
|
|
target_sources(crc32c PRIVATE ${_crc32_src})
|
|
set_property(SOURCE ${_crc32_src} PROPERTY COMPILE_OPTIONS ${ARM64_CRC_CXXFLAGS})
|
|
endif()
|
|
|
|
unset(_crc32_src)
|