mirror of
https://github.com/bitcoin/bitcoin.git
synced 2026-02-09 08:43:04 +01:00
fa5f297748
-BEGIN VERIFY SCRIPT- sed --in-place --regexp-extended \ 's;( 20[0-2][0-9])(-20[0-2][0-9])? The Bitcoin Core developers;\1-present The Bitcoin Core developers;g' \ $( git grep -l 'The Bitcoin Core developers' -- ':(exclude)COPYING' ':(exclude)src/ipc/libmultiprocess' ':(exclude)src/minisketch' ) -END VERIFY SCRIPT-
63 lines
2.1 KiB
Plaintext
63 lines
2.1 KiB
Plaintext
// Copyright (c) 2011-present The Bitcoin Core developers
|
|
// Distributed under the MIT software license, see the accompanying
|
|
// file COPYING or http://www.opensource.org/licenses/mit-license.php.
|
|
|
|
#include "macnotificationhandler.h"
|
|
|
|
#undef slots
|
|
#import <objc/runtime.h>
|
|
#include <Cocoa/Cocoa.h>
|
|
|
|
// Add an obj-c category (extension) to return the expected bundle identifier
|
|
@implementation NSBundle(returnCorrectIdentifier)
|
|
- (NSString *)__bundleIdentifier
|
|
{
|
|
if (self == [NSBundle mainBundle]) {
|
|
return @"org.bitcoinfoundation.Bitcoin-Qt";
|
|
} else {
|
|
return [self __bundleIdentifier];
|
|
}
|
|
}
|
|
@end
|
|
|
|
void MacNotificationHandler::showNotification(const QString &title, const QString &text)
|
|
{
|
|
// check if users OS has support for NSUserNotification
|
|
if(this->hasUserNotificationCenterSupport()) {
|
|
NSUserNotification* userNotification = [[NSUserNotification alloc] init];
|
|
userNotification.title = title.toNSString();
|
|
userNotification.informativeText = text.toNSString();
|
|
[[NSUserNotificationCenter defaultUserNotificationCenter] deliverNotification: userNotification];
|
|
[userNotification release];
|
|
}
|
|
}
|
|
|
|
bool MacNotificationHandler::hasUserNotificationCenterSupport(void)
|
|
{
|
|
Class possibleClass = NSClassFromString(@"NSUserNotificationCenter");
|
|
|
|
// check if users OS has support for NSUserNotification
|
|
if(possibleClass!=nil) {
|
|
return true;
|
|
}
|
|
return false;
|
|
}
|
|
|
|
|
|
MacNotificationHandler *MacNotificationHandler::instance()
|
|
{
|
|
static MacNotificationHandler *s_instance = nullptr;
|
|
if (!s_instance) {
|
|
s_instance = new MacNotificationHandler();
|
|
|
|
Class aPossibleClass = objc_getClass("NSBundle");
|
|
if (aPossibleClass) {
|
|
// change NSBundle -bundleIdentifier method to return a correct bundle identifier
|
|
// a bundle identifier is required to use OSXs User Notification Center
|
|
method_exchangeImplementations(class_getInstanceMethod(aPossibleClass, @selector(bundleIdentifier)),
|
|
class_getInstanceMethod(aPossibleClass, @selector(__bundleIdentifier)));
|
|
}
|
|
}
|
|
return s_instance;
|
|
}
|